Vorherige Seite Modell "Heizungsregelung" Nächste Seite

#Beschreibung
HIGH LEVEL COMPONENT Heizung

SUBCOMPONENTS Zimmer, Regler, Vergl

INPUT CONNECTIONS
TAussen --> (Regler.TAussen, Zimmer.TAussen);
  TSoll --> Vergl.TSoll;

OUTPUT EQUIVALENCES
TIst := Zimmer.TRaum;

COMPONENT CONNECTIONS
TIst            --> Vergl.TIst;
Vergl.TAbw      --> Regler.TAbw;
Regler.IVol     --> Zimmer.IVol;
Regler.TVorlauf --> Zimmer.TVorlauf;

INITIALIZE
TAussen := - 10;
TSoll    := + 20;
END OF Heizung



#Beschreibung
BASIC COMPONENT Zimmer
DECLARATION OF ELEMENTS
CONSTANTS
  KapLuft (REAL) :=    1.0 E+3, # spez. Waermekapazitaet der Luft [J/(kg*K)]
KapWasser (REAL) :=    4.2 E+3, # spez. Waermekap. des Wassers [J/(kg*K)]
  RhoLuft (REAL) :=    1.3    , # Dichte der Luft [kg/m^3]
RhoWasser (REAL) := 1000      , # Dichte des Wassers [kg/m^3]
  VolRaum (REAL) :=   40.0    , # Raumvolumen [m^3]
 VolHeizk (REAL) :=   10.0 E-3, # Inhalt des Heizkoerpers [m^3]
    KWand (REAL) :=    2.0    , # Waermedurchgangskoeff. Wand [W/(K*m^2)]
   KHeizk (REAL) :=   60.0    , # Waermeuebergangskoeff. Heizk. [W/(K*m^2)]
    AWand (REAL) :=   20.0    , # Flaeche der Wand [m^2]
   AHeizk (REAL) :=    6.0    , # Flaeche des Heizkoerpers [m^2]

STATE VARIABLES
CONTINUOUS
 QRaum (REAL) := 0 ,        # Waermemenge im Raum [J]
QHeizk (REAL) := 0          # Waermemenge im Heizkoerper [J]
                            # (Waermemengen bezogen auf 0 Grad Celsius)

DEPENDENT VARIABLES
CONTINUOUS
  TRaum (REAL) ,            # Lufttemperatur im Raum [Grad Celsius]
 THeizk (REAL) ,            # mittlere Wassertemperatur im Heizk. [Grad Celsius]
TAblauf (REAL)              # Wassertemperatur am Ablauf des Heizk. [Grad Celsius]

SENSOR VARIABLES
CONTINUOUS
 TAussen (REAL) :=  0 ,     # Aussentemperatur [Grad Celsius]
TVorlauf (REAL) := 60 ,     # Vorlauftemperatur des Heizk. [Grad Celsius]
    IVol (REAL) :=  0.001   # Volumenstrom durch Heizkoerper [m^3/sec]

DYNAMIC BEHAVIOUR
  TRaum :=  QRaum / (KapLuft   * VolRaum  * RhoLuft  );
 THeizk := QHeizk / (KapWasser * VolHeizk * RhoWasser);

TAblauf := 0.5 * (THeizk + TRaum);

DIFFERENTIAL EQUATIONS
QRaum'  :=   KWand     * AWand  * (THeizk - TRaum)
           - KHeizk    * AHeizk * (TRaum  - TAussen);

QHeizk' :=   KapWasser * IVol   * (TVorlauf - TAblauf)
           - KHeizk    * AHeizk * (THeizk   - TRaum);
END
END OF Zimmer



#Beschreibung
BASIC COMPONENT Regler

LOCAL DEFINITIONS
TABULAR FUNCTION StellVor (REAL --> REAL) # Vorlauftemperatur [Grad Celsius]
CONTINUOUS                                # in Abhängigkeit von der
BY LINEAR INTERPOLATION                   # Aussentemperatur [Grad Celsius]
ON  ( -100, -20, 0, 20, 100 )
--> (   80,  80, 60, 50,  50 )

TABULAR FUNCTION StellVol (REAL --> REAL) # Reglereingriff
CONTINUOUS                                # in Abhaengigkeit von der
BY LINEAR INTERPOLATION                   # Temperaturabweichung [Grad Celsius]
ON  ( -100, -5, 0.0, 5, 100 )
--> (    1,  1, 0.5, 0,   0 )

DECLARATION OF ELEMENS

CONSTANTS
A (REAL) := 4.0 E-4      # Leitungsquerschnitt [m^2]
v (REAL) := 2.5          # Fliessgeschwindigkeit [m/sec]

DEPENDENT VARIABLES
CONTINUOUS
IVol     (REAL) ,        # Volumenstrom des Heizwassers [m^3/sec]
TVorlauf (REAL)          # Vorlauftemperatur des Heizwassers [Grad Celsius]

SENSOR VARIABLES
CONTINUOUS
TAbw    (REAL) ,         # Abweichung von der Solltemperatur [Grad Celsius]
TAussen (REAL)           # Aussentemperatur [Grad Celsius]

DYNAMIC BEHAVIOUR

IVol     := StellVol (TAbw) * A * v;
TVorlauf := StellVor (TAussen);

END OF Regler



#Beschreibung
BASIC COMPONENT Vergl

DECLARATION OF ELEMENTS

DEPENDENT VARIABLES
CONTINUOUS
TAbw (REAL)           # Abweichung der Temperatur [Grad Celsius]

SENSOR VARIABLES
CONTINUOUS
TSoll (REAL) ,        # Soll-Temperatur [Grad Celsius]
TIst (REAL)           # Ist-Temperatur [Grad Celsius]

DYNAMIC BEHAVIOUR

TAbw := TIst - TSoll;

END OF Vergl